Tilda Turtle

Kommentare

Du wirst sehen, dass die meisten Beispielprogramme ausführlich kommentiert sind. Das hilft dir, den Code zu verstehen. Und wenn du eigene Programme schreibst, wird dir deine Kommentierung helfen, auch nach ein paar Tage zu verstehen, was du programmierst hast. Kommentiere immer so viel wie nötig

Syntax:
# beliebiger Text

Parameter:
alles hinter # bis zum Zeilenende.

Besonderheiten:
Weil # einen Kommentar beginnt, müssen Webfarben in Anführungszeichen stehen.

Typische Fehler:
Eine ungeschützte Webfarbe wie #33aaff wird als Kommentar behandelt.

# Das ist ein Kommentar
vor 100  # auch hinter einem Befehl

drehe

Dreht Tilda an ihrer aktuellen Position. Gezeichnet wird dabei nichts.

Syntax:
drehe winkel

Parameter:
winkel – Zahl oder Rechenausdruck in Grad. Positive Werte drehen Tilda im Uhrzeigersinn, negative Werte gegen den Uhrzeigersinn.

Besonderheiten:
Die Position bleibt gleich; nur die Blickrichtung ändert sich.

Typische Fehler:
Der Winkel darf nicht fehlen und muss ein endlicher Zahlenwert sein.

drehe 90
drehe -45
drehe 360 / 5

# Tilda dreht sich  
# Führe dieses Programm im Einzelschritt-Modus aus

# einmal drehen: Pfeilspitze zeigt nach rechts
drehe 90

# noch einmal drehen: Pfeilspitze zeigt nach unten 
drehe 90
 
# und ein letztes Mal drehen, diesmal gegen den uhrzeigersinn
# Pfeilspitze zeigt nach oben
drehe -180

vor

Bewegt Tilda in ihrer aktuellen Blickrichtung vorwärts. Ist der Stift abgesenkt, entsteht dabei eine Linie.

Syntax:
vor strecke

Parameter:
strecke – Zahl oder Rechenausdruck. Positive Werte bewegen vorwärts; negative Werte rückwärts.

Besonderheiten:
Tildas Position verändert sich, ihre Blickrichtung bleibt gleich.

Typische Fehler:
Ein fehlender oder nicht berechenbarer Ausdruck wird als Fehler gemeldet.

vor 100
vor 50 + 25
vor -30

# Ein Quadrat wird gezeichnet, indem viele Einzelschritte ausführt werden

# linke Seite
vor 100
drehe 90

# oben
vor 100
drehe 90

# rechts
vor 100
drehe 90

# unten
vor 100
drehe 90

zurück / zurueck

Bewegt Tilda entgegen ihrer aktuellen Blickrichtung. Ist der Stift abgesenkt, entsteht eine Linie.

Syntax:
zurück strecke
zurueck strecke

Parameter:
strecke – Zahl oder Rechenausdruck.

Besonderheiten:
Die Blickrichtung bleibt unverändert.

Typische Fehler:
Der Abstand darf nicht fehlen und muss berechenbar sein.

zurück 50
zurueck 25
zurück 50 / 2

# Führe dieses Programm im Einzelschritt-Modus aus

# Erst ein Stück vor
vor 100

# dann drehen 
drehe 90

# dann nochmal ein Stück vor 
vor 50

# und jetzt rückwärts - wir haben ein T auf der Zeichenfläche 
zurück 100

# dreht sich wieder in die ursprüngliche Richtung und läuft wieder rückwärts
drehe -90
zurueck 100

stift runter

Setzt Tildas Stift auf die Zeichenfläche. Bewegungen zeichnen danach Linien. Wenn du Tilda Turtle aufrufst, ist der Stift auf dem Papier abgesenkt.

Syntax:
stift runter

Parameter:
keine

Besonderheiten:
Formbefehle können unabhängig davon weiterhin eigene Randfarben zeichnen.

Typische Fehler:
Nach „stift“ muss „runter“ oder „hoch“ stehen

stift runter
vor 100

# Hier wird eine gestrichelte Linie gezeichnet
# Tilde bewegt sich immer wieder nach vorne. 
# Achte darauf, was passiert, wenn der Stift unten ist

# Standardmäßig ist der Stift auf dem Papier
vor 50 

# Stift vom Papier abheben
stift hoch

# zeichnet keinen Strich
vor 50

# Stift wieder aufs Papier setzen
stift runter

# Und zeichnen! 
vor 50

stift hoch

Hebt Tildas Stift von der Zeichenfläche ab. Tilda kann sich anschließend bewegen, ohne eine Linie zu hinterlassen. Das ist sinnvoll, wenn Tilda an eine andere Stelle auf der Zeichenflächen marschieren soll, ohne eine Spur zu hinterlassen.

Syntax:
stift hoch

Parameter:
keine

Besonderheiten:
Die nächste Position wird trotzdem vollständig berechnet.

Typische Fehler:
Nach „stift“ muss „runter“ oder „hoch“ stehen

stift hoch
vor 80
stift runter
vor 40

# Hier wird eine gestrichelte Linie gezeichnet
# Tilde bewegt sich immer wieder nach vorne. 
# Achte darauf, was passiert, wenn der Stift unten ist

# Standardmäßig ist der Stift auf dem Papier
vor 50 

# Stift vom Papier abheben
stift hoch

# zeichnet keinen Strich
vor 50

# Stift wieder aufs Papier setzen
stift runter

# Und zeichnen! 
vor 50

linie

Zeichnet eine gerade Linie als fertige Form an Tildas aktueller Position. Die halbe Linie wird in Blickrichtung gezeichnet, die andere halbe Linie gegen die Blickrichtung. Tildas Position wird nicht verändert.

Parameter:
1. länge – muss größer als 0 sein.
2. drehung – optional; zusätzlicher Winkel in Grad.
3. farbe – optional; ohne Angabe wird Tildas aktuelle Farbe verwendet.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

linie(100) 
farbe grün
linie(100, 90)
linie(100, 45, blau)
drehe 20
linie(100, keine, rot)

# Tilda zeichnet einen Tannenbaum 

# den Stamm
linie(140)

# weiter unten anfangen
zurueck 40

# Blickreichtung nach links
drehe -90

# erste Ebene zeichnen
linie(150) 

# Blickrichtung nach oben
drehe 90

# zweite Ebene 
vor 20
drehe -90
linie(120) 
drehe 90

# Ebene 3
vor 20
drehe -90
linie(100) 
drehe 90

# Ebene 4
vor 20
drehe -90
linie(80) 
drehe 90

# Ebene 5
vor 20
drehe -90
linie(50) 
drehe 90

# Ebene 6
vor 20
drehe -90
linie(20) 
drehe 90

stift hoch
zurueck 200

pfeil

Zeichnet einen Pfeil an Tildas aktueller Position.

Parameter:
1. länge – muss größer als 0 sein.
2. breite – muss größer als 0 sein.
3. drehung – optional; zusätzlicher Winkel in Grad.
4. randfarbe – optional.
5. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

pfeil(120, 40)
pfeil(120, 40, 0, dunkelgruen, hellgruen)

wellenlinie

Zeichnet eine Wellenlinie an Tildas aktueller Position. Tildas Position wird nicht verändert.

Syntax:
wellenlinie()
wellenlinie(länge, höhe, wellenzahl)
wellenlinie(länge, höhe, wellenzahl, drehung, farbe)

Parameter:
Ohne Parameter zeichnet wellenlinie() automatisch eine Wellenlinie über die sichtbare Breite der Zeichenfläche.
1. länge – gesamte Breite der Wellenlinie; muss größer als 0 sein.
2. höhe – Abstand zwischen Wellenberg und Wellental; muss größer als 0 sein.
3. wellenzahl – ganze Zahl von 1 bis 100.
4. drehung – optional; zusätzlicher Winkel in Grad.
5. farbe – optional; ohne Angabe wird Tildas aktuelle Farbe verwendet.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

wellenlinie()
wellenlinie(240, 24, 6)
wellenlinie(140, 24, 6, 10, blau)

kreis

Zeichnet einen Kreis an Tildas aktueller Position.

Parameter:
1. radius – muss größer als 0 sein.
2. randfarbe – optional; du kannst diesen Parameter weglassen oder "keine" eintragen
3. füllfarbe – optional; du kannst diesen Parameter weglassen oder "keine" eintragen

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

kreis(20)
kreis(20, rot)
kreis(20, keine, schwarz)

ellipse

Zeichnet eine Ellipse an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. drehung – optional; zusätzlicher Winkel in Grad.
4. randfarbe – optional
5. füllfarbe – optional

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

ellipse(120, 60)
ellipse(120, 60, 30, blau, hellblau)

quadrat

Zeichnet ein Quadrat an Tildas aktueller Position.

Parameter:
1. seitenlänge – muss größer als 0 sein.
2. drehung – optional; zusätzlicher Winkel in Grad.
3. randfarbe – optional
4. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

quadrat(80)
quadrat(80, 45, dunkelblau, hellblau)

rechteck

Zeichnet ein Rechteck an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. drehung – optional; zusätzlicher Winkel in Grad.
4. randfarbe – optional
5. füllfarbe – optional

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

rechteck(120, 60)
rechteck(120, 60, 0, blau, hellblau)

dreieck

Zeichnet ein Dreieck an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. drehung – optional; zusätzlicher Winkel in Grad.
4. randfarbe – optional.
5. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

dreieck(100, 80)
dreieck(100, 80, 0, rot, gelb)

vieleck

Zeichnet ein regelmäßiges Vieleck an Tildas aktueller Position.

Parameter:
1. eckenzahl – ganze Zahl von 3 bis 100.
2. radius – muss größer als 0 sein.
3. drehung – optional; zusätzlicher Winkel in Grad.
4. randfarbe – optional.
5. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

vieleck(6, 50)
vieleck(8, 60, keine, lila, helllila)
vieleck(8, 60, 45, lila, helllila)

stern

Zeichnet einen Stern an Tildas aktueller Position.

Parameter:
1. spitzenzahl – ganze Zahl von 2 bis 100.
2. außenradius – muss größer als 0 sein.
3. innenradius – muss größer als 0 und kleiner als der Außenradius sein.
4. drehung – optional; zusätzlicher Winkel in Grad.
5. randfarbe – optional.
6. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

stern(5, 60, 25)
stern(5, 60, 25, 0, rot, gelb)

bogen

Zeichnet einen elliptischen Bogen an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. startwinkel – Beginn des Bogens in Grad.
4. bogenwinkel – Länge des Bogens in Grad.
5. drehung – optional; zusätzlicher Winkel in Grad.
6. randfarbe – optional.
Eine Füllfarbe ist nicht vorgesehen.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

bogen(120, 80, 0, 180)
bogen(120, 80, 0, 270, 30, blau)

zylinder

Zeichnet einen räumlich wirkenden Zylinder an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. tiefe – muss größer als 0 sein.
4. drehung – optional; zusätzlicher Winkel in Grad.
5. randfarbe – optional.
6. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

zylinder(100, 120, 30)
zylinder(100, 120, 30, 0, dunkelblau, hellblau)

kegel

Zeichnet einen räumlich wirkenden Kegel an Tildas aktueller Position.

Parameter:
1. breite – muss größer als 0 sein.
2. höhe – muss größer als 0 sein.
3. tiefe – muss größer als 0 sein.
4. drehung – optional; zusätzlicher Winkel in Grad.
5. randfarbe – optional.
6. füllfarbe – optional; „keine“ lässt die Füllung weg.

Besonderheit:
Wenn ein Parameter optional ist, kannst Du ihn auch weglassen. Wenn Du einen Parameter weglässt, aber einen anderen setzt, der weiter rechts steht, musst Du "keine" eintragen.

kegel(100, 140, 30)
kegel(100, 140, 30, 0, braun, hellbraun)

farbe

Legt Tildas aktuelle Linienfarbe für Bewegungsbefehle fest.

Syntax:
farbe farbname
farbe "#RRGGBB"

Parameter:
farbname – eine vorhandene Tilda-Farbe, zum Beispiel rot, gruen oder dunkelblau.
Webfarbe – Zeichenkette im Format #RGB oder #RRGGBB.

Besonderheiten:
Webfarben müssen wegen des Kommentarzeichens # in Anführungszeichen stehen.

Typische Fehler:
Unbekannte Farbnamen oder ungültige Webfarben werden abgewiesen.

farbe blau
farbe hellgruen
farbe "#33aaff"

# Eine rote Stufe 
farbe rot 
vor 50
drehe 90
vor 50

# eine blaue Stufe
drehe -90 # gegen den Uhrzeigersinn drehen
farbe blau
vor 50
drehe 90 
vor 50

# und eine grüne Stufe
farbe grün
# auch möglich wäre: farbe gruen
drehe -90 # gegen den Uhrzeigersinn drehen
vor 50
drehe 90
vor 50

wiederhole

Führt einen Block mehrmals aus. Du kannst Wiederholungen auch schachteln.

Syntax:
wiederhole anzahl {
befehle
}

Parameter:
anzahl – Ausdruck, dessen Ergebnis eine ganze Zahl von 0 bis 100000 sein muss.

Besonderheiten:
Nach der öffnenden geschweiften Klammer beginnt der Block. Jeder Durchlauf verwendet denselben Ausführungspfad.

Typische Fehler:
Negative Werte, Dezimalwerte, zu große Wiederholungszahlen oder fehlende geschweifte Klammern.

wiederhole 3 {
    wiederhole 4 {
        vor 20
        drehe 90
    }
    drehe 120
}

# Tilda zeichnet ein Quadrat, indem sie viermal zeichnet und sich viermal dreht. 

wiederhole 4 {
    vor 100
    drehe 90
}

# ein weiteres Beispiel, um geschachtelte Wiederholungen zu demonstrieren
# Tilda zeichnet mehrere Quadrate, die gegeneinander gedreht sind: 

# Tilda erstmal an eine andere Position setzen 
stift hoch
drehe -90
vor 200
drehe 90
stift runter

# Erste Wiederholung 
wiederhole 8 {
    wiederhole 4 {
        vor 100
        drehe 90
    }
    drehe 45
}

schreibe

Schreibt einen Text an Tildas aktueller Position. Die aktuelle Farbe und Blickrichtung werden verwendet; Tildas Position wird nicht verändert.

Syntax:
schreibe("Text")
schreibe("Text" + Zahl)
schreibe(Zahl + Zahl)

Parameter:
text – eine Zeichenkette in doppelten Anführungszeichen.
text + zahl - eine Zeichenkette und eine Zahl: "Ergebnis ist "+ 4
zahl + zahl - gibt das Ergebnis der beiden Zahlen aus

schreibe("ABC")
schreibe("Die Antwort auf alle Fragen: " + 42)

schreibe("Hallo Welt")

Rechenausdrücke

Tilda kann rechnen! Sie versteht einfache Grundrechenarten, die Klammern und das negative Vorzeichen.

Das versteht Tilda:
+ Addition
- Subtraktion
* Multiplikation
/ Division
( ) Klammern
+wert und -wert als Vorzeichen

Parameter:
Zahlen, Variablen und unterstützte Funktionen können kombiniert werden.

Besonderheiten:
Klammern haben Vorrang und Punkt-vor-Strich

Typische Fehler:
Division durch null, unbekannte Variablen, fehlende Klammern oder nicht endliche Ergebnisse.

setze a = 10
setze b = (a + 5) * 2
vor b
drehe -(360 / 8)
schreibe(4 + 5) # Ausgabe: 9

# Kleines Einmaleins in Spalten (abgekürzt bis 5)
# Jede Einmaleins-Reihe steht in einer eigenen Spalte.

setze reihe = 1

wiederhole 5 {

    setze zahl = 1

    wiederhole 10 {

        setze ergebnis = reihe * zahl

        schreibe(reihe + " x " + zahl + " = " + ergebnis)

        # Eine Zeile nach unten
        stift hoch
        drehe 180
        vor 25
        drehe 180
        stift runter

        setze zahl = zahl + 1
    }

    # Wieder nach oben zum Anfang der Spalte
    stift hoch
    vor 250

    # Zur nächsten Spalte nach rechts
    drehe 90
    vor 170
    drehe -90
    stift runter

    setze reihe = reihe + 1
}

setze

Speichert einen Ausdruck unter einem Variablennamen. Eine bereits vorhandene Variable darf einen neuen Wert erhalten.

Syntax:
setze name = ausdruck

Parameter:
name – beginnt mit einem Buchstaben oder Unterstrich und kann danach Buchstaben, Ziffern oder Unterstriche enthalten.
ausdruck – eine Zahl, eine andere Variable, eine Funktion oder ein Rechenausdruck.

Besonderheiten:
Groß- und Kleinschreibung werden bei Variablennamen nicht unterschieden. Reservierte Namen sind nicht erlaubt.

Typische Fehler:
Fehlendes Gleichheitszeichen, fehlender Ausdruck, reservierter Name oder unbekannte Variable im Ausdruck.

setze seite = 100
setze winkel = 360 / 5
setze seite = seite + 20

# Hier legst Du fest, wie viele Quadrate gezeichnet werden sollen
setze anzQuadrate = 5

# Hier bestimmst Du, wie groß das erste Quadrat sein soll
setze größe = 50 

# Das jeweils folgende Quadrat soll größer sein als das vorige
setze vergrößerung = 0

# Wiederhole, bis alle Quadrate gezeichnet sind
wiederhole anzQuadrate {
   # Der Vergrößerungsfaktor wird bei jedem Quadrat um 1 erhöht
   # Variablen können mit einem neuen Wert belegt werden
   setze vergrößerung = vergrößerung + 1

   # Und jetzt wird ein Quadrat gezeichnet
   # das Prinzip kennst Du aus dem Beispiel bei der Wiederholung
   # neu ist nur die Vergrößerung der jeweils folgenden Quadrate
   wiederhole 4 {
      vor größe * vergrößerung
      drehe 90
   }    
}

runde

Rundet einen Zahlenwert auf die nächste ganze Zahl. Das kann sinnvoll sein, wenn du eine Schrittweite berechnet hast, und das Ergebnis keine ganze Zahl ist.

Syntax:
runde(ausdruck)

Parameter:
ausdruck – genau ein berechenbarer Zahlenwert.

Rückgabewert:
eine ganze Zahl.

Besonderheiten:
Die Funktion wird innerhalb eines Ausdrucks verwendet und zeichnet selbst nichts.

Typische Fehler:
Keine oder mehr als eine Angabe beziehungsweise ein nicht berechenbarer Wert.

setze breite = 100
setze teile = 3
setze schritt = breite / teile

vor runde(schritt)

zufallszahl

Zufallszahlen spielen in der Informatik eine große Rolle. Die Funktion zufallszahl() erzeugt eine zufällige ganze Zahl. Du kannst einen oder zwei Parameter eingeben.

Syntax:
zufallszahl(maximum)
zufallszahl(minimum, maximum)

Parameter:
maximum – bei einem Parameter liegt das Ergebnis zwischen 0 und (maximum - 1).
minimum, maximum – bei zwei Parametern sind beide Grenzen eingeschlossen. Alle Grenzen müssen ganze Zahlen sein.

Rückgabewert:
eine zufällige ganze Zahl.

Typische Fehler:
Falsche Parameterzahl, Dezimalgrenzen oder ein ungültiger Wertebereich.

vor zufallszahl(100)
drehe zufallszahl(0, 359)
setze würfel = zufallszahl(1, 6)

setze strecke = runde(zufallszahl(30, 90))
vor strecke

befehl

Definiert einen eigenen Befehl, der später wie eine Funktion aufgerufen wird. Parameter sind während des Aufrufs lokal.

Syntax:
befehl name(parameter1, parameter2) {
befehle
}

Parameter:
name – eindeutiger, nicht reservierter Befehlsname.
parameter – optionale, durch Kommas getrennte Namen.

Besonderheiten:
Beim Aufruf müssen genau so viele Argumente angegeben werden wie Parameter definiert wurden. Verschachtelte Aufrufe sind erlaubt; die Aufruftiefe ist begrenzt.

Typische Fehler:
Doppelter Befehlsname, doppelte Parameternamen, falsche Argumentzahl oder zu tiefe Rekursion.

befehl meinQuadrat(seite) {
    wiederhole 4 {
        vor seite
        drehe 90
    }
}

meinQuadrat(100)

# Ein Quadrat wird als eigener Befehl definiert und wiederholt aufgerufen

befehl zeichne_quadrat(größe) {
    wiederhole 4 {
        vor größe
        drehe 90
    }
}

farbe blau
zeichne_quadrat(80)

stift hoch
drehe 90
vor 130
drehe -90
stift runter

farbe rot
zeichne_quadrat(140)

fläche / flaeche

Sammelt die innerhalb des Blocks entstehenden Bewegungslinien zu einer geschlossenen Fläche und zeichnet Rand sowie Füllung.

Syntax:
fläche(randfarbe, füllfarbe) {
bewegungsbefehle
}

Parameter:
randfarbe – Farbname, Webfarbe oder „keine“.
füllfarbe – Farbname, Webfarbe oder „keine“.

Besonderheiten:
Die ASCII-Schreibweise „flaeche“ ist ebenfalls erlaubt. „keine“ schaltet Rand beziehungsweise Füllung ab.

Typische Fehler:
Fehlende Farben, ungültige Farbangaben oder ein nicht geschlossener Block.

fläche(blau, hellblau) {
    vor 100
    drehe 120
    vor 100
    drehe 120
    vor 100
}

flaeche(keine, "#88ccff") {
    wiederhole 4 {
        vor 60
        drehe 90
    }
}

fläche(schwarz, hellgelb){
    wiederhole 5{
        vor 50
        drehe 90
        vor 50
        drehe -90
    }
}

tildaZeichnen

Zeichnet das Maskottchen Tilda als fertige Vektorgrafik an der aktuellen Position. Ohne Größenangabe wird die Standardgröße verwendet. Tildas Position wird nicht verändert.

Syntax:
tildaZeichnen()
tildaZeichnen(größe)

Parameter:
größe – optional; positive Zahl für die Größe des Maskottchens. Ohne Angabe wird die Standardgröße 120 verwendet.

Besonderheiten:
Das Maskottchen wird als eingebaute Vektorgrafik gezeichnet.

Typische Fehler:
Eine angegebene Größe muss eine positive endliche Zahl sein.

tildaZeichnen()
tildaZeichnen(180)